Mesure de l'inclinaison et de la déclinaison d'un plan

Yvon MASSE


RESUME: Les mesures d'inclinaison et de déclinaison d'un plan ou d'un mur se font classiquement de façon indépendante. L'inclinaison se mesure simplement à l'aide d'un fil à plomb, d'un rapporteur et accessoirement d'une équerre. La mesure de la déclinaison est plus difficile a réaliser et fait souvent appel à un plan horizontal, mis en place à l'aide d'un niveau. Sur ce plan, on peut faire porter l'ombre d'un fil à plomb à midi vrai afin de relever la méridienne. Il est alors possible de mesurer la déclinaison à l'aide d'un rapporteur.
L'étude qui suit propose de trouver simultanément inclinaison et déclinaison à l'aide d'un seul relevé. En contrepartie de la simplicité du relevé il est nécessaire d'effectuer certains calculs. Ceux-ci donnent en fait deux couples de valeurs dont un seul est le bon. Ces inconvénients sont toutefois minimes si on a recourt à l'informatique et car, bien souvent, il n'y a pas d'ambiguïté sur le choix du bon couple de valeurs. Cependant, si le doute persiste, une seconde mesure indiquera clairement le choix à effectuer.
La précision peut également être améliorée en faisant la moyenne du résultat de plusieurs relevés.

I/ Principe

Mesurer les coordonnées du soleil dans le repère du cadran à un instant quelconque. Connaissant par ailleurs les coordonnées locales du soleil au même instant, l'orientation du cadran se met en équation. La résolution montre qu'il existe deux solutions.

II/ Outillage

Une planchette comprenant:
Planchette

III/ Relevé

Appliquer la planchette sur le plan à mesurer. Orienter l'axe des y à droite en regardant la planchette (l'axe des x est alors dirigé vers le bas). Régler l'horizontalité de l'axe des y puis relever l'heure et les coordonnées de l'ombre de la pointe du style à cet instant.
Et c'est tout...

III/ Calculs

Configurer le programme ci-dessous avec le fuseau horaire en vigueur et la longueur du style droit. Lancer le programme et répondre aux questions posées: Le programme affiche alors les résultats en degré, la déclinaison est positive à l'ouest, l'inclinaison est nulle pour un plan horizontal et égale à 90° pour un plan vertical. Deux couples de résultat sont fournis. Si le soleil est situé devant le plan vertical passant par l'axe des y (ce qui est toujours le cas pour un mur), c'est le premier couple qui est le bon. Si le soleil est situé derrière, il faut utiliser le second couple.

IV/ Astuces

Afin d'augmenter la précision des relevés on peut remplacer la pointe du style droit par la croisée de deux fils.

Quand seule la mesure de la déclinaison est nécessaire et que l'ombre de la pointe du gnomon sort de la planchette, on peut bien sur incliner différemment celle-ci. Il suffit de maintenir l'axe des y horizontal et parallèle au plan à mesurer.

V/ Le programme

L'écriture proposée ici est faite en Qbasic de Microsoft mais elle est facilement adaptable à tout autre langage.

Remarque: Ce programme est valable en tout point du globe sans aucune modification.


REM Constantes
k = .0172024
jm = 674.03
jl = 752.2
e = .0167
ob = .4091
pi = 3.141593: dr = pi / 180: hr = pi / 12

REM fuseau horaire et hauteur du style droit
fh = 2: g = 80

INPUT "Longitude, Latitude"; lo, la
lo = lo * dr: dp = (90 - la) * dr

INPUT "Jour, Mois, Année"; jo, mo, an
IF mo < 3 THEN mo = mo + 12: an = an - 1
INPUT "Heure (légale), Minute"; hh, mn

REM Nombre de jours écoulés depuis
REM le 1 Mars O h TU de la dernière année bissextile + 2 ans

h = hh + mn / 60 - fh
j = 365 * (an - 4 * INT(an / 4)) + INT(30.61 * (mo + 1)) + jo + h / 24 - 853

REM Longitude vraie du soleil
m = k * (j - jm): l = k * (j - jl)
s = l + 2 * e * SIN(m) + 1.25 * e * e * SIN(2 * m)

REM Coordonnées locales du soleil
x = COS(s): y = COS(ob) * SIN(s): z = SIN(ob) * SIN(s)
r = l + h * hr - lo - pi: GOSUB 1300: r = dp: GOSUB 1200

REM Correction de la réfraction
IF z < .9999 THEN
  ht = ATN(z / SQR(1 - z * z))
  rf = .000291 / TAN(ht + .00223 / (ht + .077))
  cr = COS(rf) - TAN(ht) * SIN(rf)
  x = cr * x: y = cr * y: z = SIN(ht + rf)
END IF

REM Coordonnées du soleil dans le repère du cadran
INPUT "Ombre de la pointe du style droit X,Y :"; xp, yp
rc = SQR(xp * xp + yp * yp + g * g)
xp = -xp / rc: yp = -yp / rc: zp = g / rc

REM calcul de l'inclinaison
rc = SQR(1 - z * z - yp * yp)
i1 = 2 * ATN((-xp + rc) / (z + zp)): i2 = 2 * ATN((-xp - rc) / (z + zp))

REM calcul de la déclinaison
d1 = 2 * ATN((x - rc) / (y + yp)): d2 = 2 * ATN((x + rc) / (y + yp))

REM affichage des résultats
PRINT "i1="; i1 / dr, "d1="; d1 / dr
PRINT "i2="; i2 / dr, "d2="; d2 / dr

END

1200 REM Rotation de l'angle r autour de l'axe y
rx = COS(r) * x - SIN(r) * z: rz = SIN(r) * x + COS(r) * z
x = rx: z = rz: RETURN

1300 REM Rotation de l'angle r autour de l'axe z
rx = COS(r) * x + SIN(r) * y: ry = -SIN(r) * x + COS(r) * y
x = rx: y = ry: RETURN


Télécharger le fichier source

Retour à la page d'accueil -o- Reveno al la akcepta retpagho

Date de création: 10 Juin 97
Date de dernière mise à jour: 2 Juin 99