Ephéméride pour gnomoniste

RESUME: L'art de tracer des cadrans solaires ou gnomonique nécessite bien souvent l'usage d'une table de l'équation du temps ou de la déclinaison du soleil. L'utilisation d'un programme d'éphéméride astronomique pour obtenir ces valeurs est une approche assez longue à mettre en oeuvre. En effet ce type de programme utilise un grand nombre de constantes et de calculs nécessaires à une grande précision sur plusieurs dizaines voire centaines d'années. Ce n'est pas le cas en gnomonique où seul le cycle annuel du soleil est considéré et où la précision acceptée est plus faible.
L'éphéméride proposée ici est volontairement simplifiée et les constantes utilisées sont réduites au stricte minimum. La précision obtenue est toutefois honorable car l'équation du temps est obtenue à +/- 10 s de temps près et la déclinaison du soleil à +/- 0,15°. Bien que cette dernière valeur semble non négligeable, c'est pourtant l'approximation qui est toujours faite en gnomonique car on ne tient jamais compte du décalage progressif de la déclinaison pendant la période de 4 ans qui se termine par une année bissextile.
L'avantage d'un programme ainsi épuré est qu'il peut facilement être introduit sur une simple calculette programmable. Sa simplicité permet également une approche didactique aux calculs de la position du soleil.
Le programme proposé ici calcule également la position de l'ombre d'un style droit sur un cadran d'orientation quelconque.

I/ Les paramètres

Pour effectuer le calcul de l'ombre du style, le programme doit être configuré par les paramètres suivants:

La longitude du lieu où est situé le cadran, exprimée en degré et positive à l'ouest du méridien de Greenwich
La latitude, exprimé en degré et positive pour l'hémisphère nord
Le fuseau horaire en vigueur
La déclinaison du cadran, exprimée en degré et positive à l'ouest
L'inclinaison, nulle pour un cadran horizontal et égale à 90° pour un cadran vertical
La longueur du style droit, l'unité utilisée sera aussi celle des résultats

II/ Origine du temps et unité

L'origine du temps est prise le 1 Mars à 0 h UT, l'unité utilisée est la journée. Ainsi par exemple, pour le 2 Mars à midi UT le temps aura la valeur 1,5.

III/ Système de coordonnées

Le programme utilise les coordonnées rectangulaires du soleil projeté sur une sphère de rayon unité. Le passage d'un repère à un autre se fait par rotation de repère.

IV/ Définition des repères

1/ Repère équatorial

Axe des x: En direction du point vernal
Axe des y: Sur l'équateur en direction de l'ascension droite 6 h
Axe des z: En direction du pôle nord

2/ Repère de calcul de l'équation du temps

Axe des x: En direction du soleil moyen
Axe des y: Sur l'équateur, à 90° à l'est de l'axe des x
Axe des z: En direction du pôle nord

Le passage du précédent repère à celui-ci s'effectue par rotation dans le sens direct autour de l'axe z de l'angle de la longitude moyenne du soleil.

3/ Repère local

Axe des x: Horizontal en direction du sud
Axe des y: Horizontal en direction de l'est
Axe des z: Vertical en direction du zénith

Le passage du précédent repère à celui-ci s'effectue par les rotations suivantes:

Dans le sens direct autour de l'axe z de l'angle horaire - longitude - 180°
Dans le sens direct autour de l'axe y de l'angle 90° - latitude

4/ Repère du cadran

Origine: Pied du style droit
Axe des x: Sur le plan du cadran, sur la ligne de plus grande pente, direction descendante
Axe des y: Sur le plan du cadran, horizontal, en direction de la droite
Axe des z: Perpendiculaire au plan du cadran, en direction de l'avant du cadran

Le passage du précédent repère à celui-ci s'effectue par les rotations suivantes:

Dans le sens non direct autour de l'axe z de l'angle de la déclinaison
Dans le sens direct autour de l'axe y de l'angle de l'inclinaison

V/ Les constantes

k: Vitesse angulaire moyenne en radian/jour de la terre autour du soleil
jm: Jour du périhélie
jl: Jour de la longitude moyenne nulle
e: Excentricité de l'orbite de la terre
ob: Obliquité de l'écliptique en radian

VI/ Le programme

L'écriture proposée ici est faite en Qbasic de Microsoft mais elle est facilement adaptable à tout autre langage.

Remarque: Ce programme est valable en tout point du globe sans aucune modification.

REM Constantes
k = .0172024
jm = 308.67
jl = 21.55
e = .0167
ob = .4091
pi = 3.141593: dr = pi / 180: hr = pi / 12

REM Coordonnées géographiques et fuseau horaire
lo = -2.1: la = 49.1: fh = 1
lo = lo * dr: dp = (90 - la) * dr

REM Déclinaison et inclinaison d'un cadran, hauteur de son style droit
d = 12: i = 45: g = 10
d = d * dr: i = i * dr

INPUT "Jour, Mois"; jo, mo
IF mo < 3 THEN mo = mo + 12
INPUT "Heure (légale), Minute"; hh, mn

REM Heure TU
h = hh + mn / 60 - fh

REM Nombre de jours écoulés depuis le 1 Mars O h TU
j = INT(30.61 * (mo + 1)) + jo + h / 24 - 123

REM Anomalie et longitude moyenne
m = k * (j - jm): l = k * (j - jl)

REM Longitude vrai
s = l + 2 * e * SIN(m) + 1.25 * e * e * SIN(2 * m)

REM Coordonnées rectangulaires du soleil dans le repère équatorial
x = COS(s): y = COS(ob) * SIN(s): z = SIN(ob) * SIN(s)

REM Equation du temps et déclinaison
r = l: GOSUB 1300
PRINT "Equation du temps (mn):"; ATN(y / x) * 60 / hr
PRINT "Déclinaison (°):"; ATN(z / SQR(1 - z * z)) / dr

REM Coordonnées locales du soleil
r = h * hr - lo - pi: GOSUB 1300: r = dp: GOSUB 1200

REM Coordonnées du soleil dans le repère du cadran
r = -d: GOSUB 1300: r = i: GOSUB 1200

REM Position de l'ombre du style droit
PRINT "X:"; -g * x / z
PRINT "Y:"; -g * y / z

END

1200 REM Rotation de l'angle r autour de l'axe y
rx = COS(r) * x - SIN(r) * z: rz = SIN(r) * x + COS(r) * z
x = rx: z = rz: RETURN

1300 REM Rotation de l'angle r autour de l'axe z
rx = COS(r) * x + SIN(r) * y: ry = -SIN(r) * x + COS(r) * y
x = rx: y = ry: RETURN

Télécharger le fichier source

Retour à la page d'accueil -o- Reveno al la akcepta retpagho

Date de création: 10 Juin 97
Date de dernière mise à jour: 9 Juillet 97